finish         			! kilépés minden process-ből
/clear      			! memória törlése

/cwd, 'D:\Google_Drive\01_education\07_VEA\19-20-1\APDL\feladat2-eromero_cella'
*abbr,START,/input,SA_eromero_cella_v1,ans

! ADATBEVITEL !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Geometriai adatok
l=80        			! az erőmérő cella hossza
a=12        			! az erőmérő cella magassága
s=9         			! furatok középpontjainak távolsága
d=10        			! furatok átmérője
b=8         			! üreg kibővítése egy négyzettel(élhossz: 8mm)

! Anyagtulajdonságok
E=2e5 				    ! rugalmassági modulusz 
nu=0.3 				    ! Poisson tényező

! Peremfeltételek
l0=20      			    ! megfogás hossza
l1=30       			! terhelés hossza
n=1 					! terhelési eset

! ELŐKÉSZÍTÉS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/prep7      			! belépés a preprocesszorba

! Geometria megrajzolása
blc4,0,0,l,a         	! téglalap rajzolása
cm,cella,area          	! táglalap elnevezése cellának

cyl4,l/2-s/2,a/2,d/2   	! baloldali furat megadása
cyl4,l/2+s/2,a/2,d/2   	! jobboldali furat megadása
blc5,l/2,a/2,b,b       	! üreg kibővítése
cmsel,u,cella          	! első téglalap (cella) elrejtése az aktuális elemek közül
cm,ureg,area           	! ami most látható (2 furat + négyzet) elnevezése ureg-nek

allsel                	! minden kijelölése (újra minden látható lesz)
asba,cella,ureg			! az ureg kivonása a cellából

! Geometria előkészítése peremfeltételekhez
lsel,s,loc,y,0          ! az alsó vonal kijelölése
ldiv,all,l0/l           ! a kijelölt vonal felosztása 20 és 60 mm-es szakaszokra

lsel,s,loc,y,a          ! a felső vonal kiválasztása
ldiv,all,l1/l           ! a kijelölt vonal felosztása 30 és 50 mm-es szakaszokra

lsel,r,loc,x,l-l1,l     ! a 30 mm-es szakasz kijelölése
ldiv,all,,,3            ! a kijelölt szakasz felosztása 3 egyenlő részre

! Anyagtulajdonságok megadása:
mp,ex,1,E 				! rugalmassági modulusz               
mp,nuxy,1,nu           	! Poisson tényező   

! Végeselem háló beállítása, elkészítése 
et,1,182,,,2        	! elemtípus: 182: 2D lineáris, 2:SA
mshape,1,2d				! elem alakja (0: négyszög, 1: háromszög)
esize,5                 ! elemméret
amesh, all		        ! összes felület behalozasa

! Peremfeltételek megadása
lsel,s,loc,y,0          ! a befogás helyének kijelölése
lsel,r,loc,x,0,l0
nsll,s,1				! összes csomópont kijelölése az aktív vonalon

d,all,ux,0				! A kijelölt csomópontok megfogása x irányban
d,all,uy,0				! A kijelölt csomópontok megfogása y irányban

lsel,s,loc,y,a			! a megadott terhelési szakasz kijelölése
lsel,r,loc,x,l-l1+(n-1)*l1/3,l-l1+n*l1/3
sfl,all,pres,1       	! terhelés elhelyezése (p=1N/mm^2)

allsel 					! minden kijelölése (újra minden látható lesz)

finish

! SZÁMÍTÁS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/sol					! belépés a solver-be
solve					! számítás elvégzése
finish					! kilépés a solver-ből


! KIÉRTÉKELÉS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/post1					! belépés a postprocessor-ba

plnsol,u,sum,2,1.0		! elmozdulásmező szemléltetése (2: eredeti alak is, 1.0: nagyítás)

/wait,2					! várakozás 2 sec-ig

plnsol, epel, x,2,1.0  	! epsilon_x fajlagos nyúlás szemléltetése

/wait,2					! várakozás 2 sec-ig

plnsol,s,eqv,2,1.0		! redukált feszültség szemléltetése

/status,all