finish         			! kilépés minden process-ből
/clear      			! memória törlése

/cwd, 'D:\Google_Drive\01_education\07_VEA\19-20-1\APDL\feladat2-eromero_cella'
*abbr,START,/input,SA_eromero_cella_v3,ans

! ADATBEVITEL !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! Geometriai adatok
l=80        			! az erőmérő cella hossza
a=12        			! az erőmérő cella magassága
s=9         			! furatok középpontjainak távolsága
d=10        			! furatok átmérője
b=8         			! üreg kibővítése egy négyzettel(élhossz: 8mm)

! Anyagtulajdonságok
E=2e5 				    ! rugalmassági modulusz 
nu=0.3 				    ! Poisson tényező

! Peremfeltételek
l0=20      			    ! megfogás hossza
l1=30       			! terhelés hossza
n=1 					! terhelési eset

! ELŐKÉSZÍTÉS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/prep7      			! belépés a preprocesszorba

! Geometria megrajzolása
blc4,0,0,l,a         	! téglalap rajzolása
cm,cella,area          	! táglalap elnevezése cellának

cyl4,l/2-s/2,a/2,d/2   	! baloldali furat megadása
cyl4,l/2+s/2,a/2,d/2   	! jobboldali furat megadása
blc5,l/2,a/2,b,b       	! üreg kibővítése
cmsel,u,cella          	! első téglalap (cella) elrejtése az aktuális elemek közül
cm,ureg,area           	! ami most látható (2 furat + négyzet) elnevezése ureg-nek

allsel                	! minden kijelölése (újra minden látható lesz)
asba,cella,ureg			! az ureg kivonása a cellából

! Geometria előkészítése peremfeltételekhez
lsel,s,loc,y,0          ! az alsó vonal kijelölése
ldiv,all,l0/l           ! a kijelölt vonal felosztása 20 és 60 mm-es szakaszokra

lsel,s,loc,y,a          ! a felső vonal kiválasztása
ldiv,all,l1/l           ! a kijelölt vonal felosztása 30 és 50 mm-es szakaszokra

lsel,r,loc,x,l-l1,l     ! a 30 mm-es szakasz kijelölése
ldiv,all,,,3            ! a kijelölt szakasz felosztása 3 egyenlő részre

! Geometria előkészítése hálózáshoz
lsel,none				! vonal kijelölések megszüntetése

ksel,s,loc,y,a/2+b/2	! y=a/2+b/2 pontok kijelölése
*get,num1,kp,0,num,min	! fenti kijelölésből a legkisebb sorszámú pont sorszáma -> num1
*get,num2,kp,0,num,max	! fenti kijelölésből a legnagyobb sorszámú pont sorszáma -> num2
*get,n1x,kp,num1,loc,x	! num1 sorszámú pont x koordinátája -> n1x
*get,n2x,kp,num2,loc,x	! num2 sorszámú pont x koordinátája -> n2x

*get,mxnum,kp,0,num,maxd	! legnagyobb csomópont sorszám -> mxnum

k,mxnum+1,n1x,a			! mxnum+1 sorszámú pont elhelyezése n1x,a helyre
k,mxnum+2,n2x,a			! mxnum+2 sorszámú pont elhelyezése n2x,a helyre
l,num1,mxnum+1			! vonal a num1 és mxnum+1 sorszámú pontok közé
l,num2,mxnum+2			! vonal a num2 és mxnum+2 sorszámú pontok közé

ksel,s,loc,y,a/2-b/2	! y=a/2-b/2 pontok kijelölése 
*get,num1,kp,0,num,min	! fenti kijelölésből a legkisebb sorszámú pont sorszáma -> num1
*get,num2,kp,0,num,max	! fenti kijelölésből a legnagyobb sorszámú pont sorszáma -> num2
*get,n1x,kp,num1,loc,x	! num1 sorszámú pont x koordinátája -> n1x
*get,n2x,kp,num2,loc,x	! num2 sorszámú pont x koordinátája -> n2x

*get,mxnum,kp,0,num,maxd ! legnagyobb csomópont sorszám -> mxnum

k,mxnum+1,n1x,0			! mxnum+1 sorszámú pont elhelyezése n1x,0 helyre
k,mxnum+2,n2x,0			! mxnum+2 sorszámú pont elhelyezése n2x,0 helyre
l,num1,mxnum+1			! vonal a num1 és mxnum+1 sorszámú pontok közé	
l,num2,mxnum+2			! vonal a num2 és mxnum+2 sorszámú pontok közé


*get,mxnum,kp,0,num,maxd    ! legnagyobb csomópont sorszám -> mxnum
k,mxnum+1,l/2-s/2-a/8,a/2	! mxnum+1 sorszámú pont elhelyezése
k,mxnum+2,l/2-s/2-a,a/2+2*a	! mxnum+2 sorszámú pont elhelyezése
k,mxnum+3,l/2-s/2-a,a/2-2*a	! mxnum+3 sorszámú pont elhelyezése
l,mxnum+1,mxnum+2			! vonal mxnum+1 és mxnum+2 sorszámú pontok közé
l,mxnum+1,mxnum+3			! vonal mxnum+1 és mxnum+2 sorszámú pontok közé

*get,mxnum,kp,0,num,maxd	! legnagyobb csomópont sorszám -> mxnum
k,mxnum+1,l/2+s/2+a/8,a/2	! mxnum+1 sorszámú pont elhelyezése
k,mxnum+2,l/2+s/2+a,a/2+2*a	! mxnum+2 sorszámú pont elhelyezése
k,mxnum+3,l/2+s/2+a,a/2-2*a	! mxnum+3 sorszámú pont elhelyezése
l,mxnum+1,mxnum+2			! vonal mxnum+1 és mxnum+2 sorszámú pontok közé
l,mxnum+1,mxnum+3			! vonal mxnum+1 és mxnum+2 sorszámú pontok közé

cm,cut,line					! kijelölt vonalak elnevezése cut-nak
allsel						! minden kijelölése

asbl,all,cut				! cut vonalak kivonása mindenből

aplot						! minden plottolása

asel,s,loc,x,l/2-s/2-d/2,l/2+s/2+d/2	! megadott x koordináták közti felületek kijelölése

cm,thin,area				! a kijelölt felületek elnevezése thin-nek
asel,inve					! a kijelölés invertálása
cm,thick,area				! a kijelölt terület elnevezése thick-nek

allsel						! minden kijelölése

! Anyagtulajdonságok megadása:
mp,ex,1,E 					! rugalmassági modulusz               
mp,nuxy,1,nu           		! Poisson tényező   

! Végeselem háló beállítása, elkészítése 
et,1,182,,,2      	   	 	! elemtípus: 182: 2D, 2:SA
mshape,0,2d					! elem alakja (0: négyszög, 1: háromszög)
mshkey,1               	    ! 1:mapped 0:free

es=(a-d)/4
desize,1,1,9999,,,es,es

cmsel,s,thin				! thin tartomány kiválasztása
*get,numa,area,0,count		! a thin tartományon belüli felületek száma -> numa

aa=0
*do,i,1,numa				! i=1 től numa-ig
   cmsel,s,thin				! thin tartomány kijelölése
   *get,aa,area,aa,nxth		! aa utáni legkisebb sorszámú felület sorszáma -> aa
   asel,s,area,,aa			! aa sorszámú felület kiválasztása
   lsla,s					! a kijelölt felületen belül az összes vonal kijelölése
   ksll,s					! a kijelölt vonalakon belül az összes pont kijelölése
kk=1000				    	! kk=1000 pontsoszám megadása
   *get,kk1,kp,kk,nxtl		! kk-nál kisebb, legnagyobb sorszámú pont sorszáma -> kk1
   *get,kk2,kp,kk1,nxtl		! kk1-nél kisebb, legnagyobb sorszámú pont sorszáma -> kk2
   *get,kk3,kp,kk2,nxtl		! kk2-nél kisebb, legnagyobb sorszámú pont sorszáma -> kk3
   *get,kk4,kp,kk3,nxtl		! kk3-nál kisebb, legnagyobb sorszámú pont sorszáma -> kk4
   amap,aa,kk1,kk2,kk3,kk4	! kk1,kk2,kk3,kk4 pontok által definiált, aa sorszámú felület hálózása
*enddo				    	! do ciklus lezárása

cmsel,s,thick				! thick tartomány kiválasztása
desize,1,1,9999,,,es/2,a/4,0.2	! elemméret megadása
mshape,1,2d					! 2d háromszög elem definiálása
mshkey,0					! szabad háló definiálása
amesh,thick					! thick tartomány behálózása

allsel						! minden kijelölése

! Peremfeltételek megadása
lsel,s,loc,y,0          ! a befogás helyének kijelölése
lsel,r,loc,x,0,l0
nsll,s,1				! összes csomópont kijelölése az aktív vonalon

d,all,ux,0				! A kijelölt csomópontok megfogása x irányban
d,all,uy,0				! A kijelölt csomópontok megfogása y irányban

lsel,s,loc,y,a			! a megadott terhelési szakasz kijelölése
lsel,r,loc,x,l-l1+(n-1)*l1/3,l-l1+n*l1/3
sfl,all,pres,1       	! terhelés elhelyezése (p=1N/mm^2)

allsel 					! minden kijelölése (újra minden látható lesz)

finish

! SZÁMÍTÁS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/sol					! belépés a solver-be
solve					! számítás elvégzése
finish					! kilépés a solver-ből


! KIÉRTÉKELÉS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/post1					! belépés a postprocessor-ba

plnsol,u,sum,2,1.0		! elmozdulásmező szemléltetése (2: eredeti alak is, 1.0: nagyítás)

/wait,4					! várakozás 4 sec-ig

plnsol, epel, x,     	! epsilon_x fajlagos nyúlás szemléltetése

/wait,4					! várakozás 4 sec-ig

plnsol,s,eqv,   		! redukált feszültség szemléltetése

/status,all