finish				! kilépés minden folyamatból
/clear				! memória törlése

/cwd,'J:\Google Drive\01_education\07_VEA\18-19-2\gyak10'
*abbr,felfogato,/input,gyak10,ans

/prep7				! belépés a preprocessorba
/view,1,1,2,3			! nézet beállítása

blc4,-10,-5,60,5,20		! téglatest (bal alsó sarok (x,y), szélesség, magasság, mélyésg)
blc4,-10,0,10,6,20		
blc4,-10,-25,10,20,20
blc4,0,-25,50,20,5
vglue,all				! összes téglalap összeragasztása

*get,nop,kp,0,num,maxd	! pontok számának lekérése

asel,none				! összes felület inaktiválása
vsel,none				! összes térfogat inaktiválása

/pnum,kp,1

k,nop+1,0,-25			! nop+1-edik pont (0,-25) helyre
k,nop+2,50,-5
k,nop+3,50,-25
a,nop+1,nop+2,nop+3		! háromszög a fenti 3 pontból

vext,all,,,,,5			! háromszög extrudálása 5mm-rel

cm,cut,volu			! aktív térfogat elnevezése cut-nak
vsel,inve				! kijelölés invertálása
cm,sum,volu			! aktív térfogat elnevezése sum-nak
allsel				! minden kijelölése
vsbv,sum,cut			! sum téerfogatból cut térfogat kivágása

*get,nop,kp,0,num,maxd	! pontok számának lekérése
asel,none				! összes felület inaktiválása
vsel,none				! összes térfogat inaktiválása

k,nop+1,-10,6,5
k,nop+2,-10,6,20
k,nop+3,-5,6,20
a,nop+1,nop+2,nop+3		! háromszög a fenti 3 pontból
vext,all,,,,-31			! háromszög extrudálása 31mm-rel

cm,cut,volu
vsel,inve
cm,sum,volu
allsel
vsbv,sum,cut

*get,nop,kp,0,num,maxd	! pontok számának lekérése
asel,none
vsel,none

k,nop+1,0,10,0
k,nop+2,1,10,0
k,nop+3,0,10,-1
kwplan,1,nop+1,nop+2,nop+3	! új munkasík definiálása

cyl4,-5,0,3			! 3mm sugarú kör az új munkasíkra

vext,all,,,,-40
cm,cut,volu
vsel,inve
cm,sum,volu
allsel
vsbv,sum,cut

vplot					! térfogat plottolása

wpcsys,1,0				! koordinátarendszer visszaállítása
/view,1,1,2,3
/replot


asel,s,loc,y,0			! y=0 felület kiválasztása
asel,r,loc,x,0,60		! a fenti felületből x=(0,60) közti felület
da,all,uy,0			! felületen y irányú elmozdulás 0

asel,s,loc,x,0
asel,r,loc,y,0,6
da,all,ux,0

asel,s,loc,z,0
da,all,uz,0

allsel

mp,ex,1,2e5
mp,nuxy,1,0.3

et,1,solid186			! másodfokú 3d elem
esize,2				! 2 mm elemméret
mshape,1,3d			! tetraéder elem
mshkey,0				! szabad háló
vmesh,all				! összes térfogat behálózása

nsel,none				! összes csomópont inaktiválása
asel,s,loc,y,-25		! y=-25 felület kiválasztása
nsla,s,1				! aktív felület összes csomópontjának kijelölése
cm,slaves,node			! csomópontok elnevezése slaves-nek
nsel,none				! összes csomópont inaktiválása
n,,20,20,0				! csomópont elhelyezése
cm,master,node			! csomópont elnevezése master-nek

et,2,mpc184			! 2. elemtípus: merev elem
keyopt,2,1,0			! merev link elem
type,2				! 2-es elemtípus aktiválása

*get,masternum,node,0,num,max	! master csomópont sorszáma

cmsel,s,slaves			! salves csomópontok kiválasztása
*get,nos,node,0,count		! slaves csomópontok száma ->nos

slavenum=0				! slacenum=0 inicializálás do ciklushoz
*do,i,1,nos
	*get,slavenum,node,slavenum,nxth	! köv, node sorszáma
	e,masternum,slavenum	! aktív elem elhelyezése masternum, slavenum közé
*enddo

cmsel,s,master			! master kiválasztása
f,all,fy,100			! f=100N erő alkalmazása

allsel				! minden kiválasztása

finish				! kilépés a preprocessorból

/solu
solve
finish

/post1
esel,s,type,,1
plnsol,s,eqv
/eof
nsel,s,loc,y,0
nsel,r,loc,x,0,60
esln,s
plnsol,s,y