finish				! kilépés minden folyamatból
/clear				! memória törlése

/cwd,'J:\Google Drive\01_education\07_VEA\19-20-1\ADPL\rugalmas_felter'
*abbr,start,/input,gyak9,ans


! ADATBEVITEL !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
Rhs=10000				! rugalmas féltér sugara
rcyl=25				! merev henger sugara
depth=0.01				! benyomás mélysége
rmax=30				! kontakt tartomány sugara
ces=0.1				! kontakt tartomány elemmérete mm-ben
Ren=10				! féltér tartomány elemmérete kerületi elemszámban
lay=20				! kontankt tartomány rétegeinek száma
E=2e5					! rugalmassági modulusz
nu=0.3				! Poisson tényező

! PREPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/prep7				! belépés a preprocessorba

! Geometria megrajzolása, előkészítése hálózáshoz:
cyl4,0,0,Rhs,0,Rhs,-90	! negyedkör megrajzolása (középpont, kezdő sugár, szög, vég sugár, szög)
k,10,0,-ces*lay			! 10-es pont elhelyezése (0,-2)mm-re
k,11,rmax,-ces*lay		! 11-es pont elhelyezése (30,-2)mm-re
k,12,rmax,0			! 12-es pont elhelyezése (30,0)mm-re
lsel,none				! összes vonal inaktiválása
l,10,11				! vonal 10-es és 11-es pontok közé
l,11,12				! vonal 11-es és 12-es pontok közé

asbl,all,all			! összes felületből az összes aktív vonal kivonása ->felület elvágása

asel,s,loc,x,0,rmax		! 0 és 30 mm közti felületek kijelölése
cm,contarea,area		! kijelölt felület elnevezése contarea-nak

asel,inve				! kijelölés megfordítása
cm,halfspace,area		! kijelölt felület elnevezése halfspace-nek

allsel				! minden kijelölése

! Anyagtulajdonságok megadása:
mp,ex,1,E				! rugalmassági modolusz megadása
mp,nuxy,1,nu			! Poisson tényező megadása

! Hálózás
et,1,183,,,1			! 2D elemtípus megadása(182: lineáris, 183: másodfokú)
!keyopt,1,3,1			! 2D feladat típusa (1:FSZ, 2:SA, 3:ÁSF)

mshape,0,2d			! elem alakja (0:négszög, 1:háromszög)
mshkey,0				! hálózási technika (0: struktúrált, 1:szabad)
desize,1,1,9999,,,ces,ces	! elemméret megadása
amesh,contarea			! contarea tartomány behálózása

mshape,1,2d			! elem alakja (0:négszög, 1:háromszög)
mshkey,0				! hálózási technika (0: struktúrált, 1:szabad)
oes=Rhs*3.1415/2/Ren
desize,1,1,9999,,,ces,oes,0.2	!elemméret megadása
amesh,halfspace			! halfspace tartomány behálózása

allsel				! minden kijelölése

! Peremfeltételek megadása
csys,1				! áttérés henger koordináta rendszerre
nsel,s,loc,x,Rhs		! origótól Rhs távolságra lévő csomópontok kijelölése
d,all,ux,0				! sugárirányú elmozdulás 0
d,all,uy,0				! érintő irányú elmozdulás 0
csys,0				! visszatérés derékszögű koordinátarendszerbe
nsel,s,loc,y,0			! y=0-nál lévő csomópontok kijelölése
nsel,r,loc,x,0,rcyl		! a fenti kijelölésből x=(0,rcyl) közti pontok kijelölése
d,all,uy,-depth			! -depth mértékű eltolása a kijelölt pontoknak

allsel				! minden kijelölése
finish				! kilépés a preprocessorból

! SOLVING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/sol					! belépés a solverbe
solve					! számítás elvégeztetése
finish				! kilépés a solverből

! POSTPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/post1				! belépés a postprocessorba
plnsol,u,sum,0,1.0		! elmozdulásmező szemléltetése
!plnsol,s,y!,0,1.0		! szigma_y feszültségeloszlás szemléltetése
/eof
! Függvényábrázolások:
path,cont,2,3,1000		! nyomvonal definiálása (név,definiáló pontok száma, változók száma
					! pontok közti felosztás)
ppath,1,,0,0			! nyomvonal kezdőpontja
ppath,2,,rcyl,0			! nyomvonal végpontja
pdef,cpfem,s,y			! 5.ábrázolandó változó: kontakt nyomás(=szigma y) végeselemből
pdef,cpan,s,y			! 6.ábrázolandó változó: kontakt nyomás analitikusan (felül lesz írva)
pdef,cpdif,s,y			! 7.ábrázolandó változó: eltérés a két nyomás között
pcalc,add,cpfem,cpfem,,-1	! cpfem szorzása -1-gyel (nyomás szigma_y -1-szerese)

paget,cpmat,table		! nyomvonalinformációk cpmat nevű mátrixba rendezése

*get,row,parm,cpmat,dim,1	! cpmat mátrix sorainak száma
*get,col,parm,cpmat,dim,2	! cpmat mátrix oszlopainak száma

p0=(E*depth)/(3.1415*(1-nu*nu)*rcyl)	! analitikus p0 kiszámítása

*do,i,1,row
	cpmat(i,6)=(p0/sqrt(1-(cpmat(i,1)*cpmat(i,1)/(rcyl*rcyl))))			! cpmat 6.oszlopa
	cpmat(i,7)=cpmat(i,5)-cpmat(i,6)								! cpmat 7.oszlopa
*enddo

paput,cpmat,table		! frissített cpmat lekérése	

/yrange,0,200			! y tengely határai
plpath,cpan,cpfem			! függvény(ek) ábrázolása

*get,nn,node,0,count		! csomópontszám lekérése