! VEMA 2.gyak
! Síkbeli rácsos tartó
! [N,mm,MPa]

FINISH       ! kilépés minden folyamatból
/CLEAR       ! memória törlése 

/CWD, 'D:\Google_Drive\01_education\05A_VEMA\gyakok21221\gyak2' ! munkakönyvtár beállítása 
*ABBR,START,/input,truss2D,ans  ! START gomb létrehozása ami beolvassa a truss2D.ans fájlt 

/PNUM,kp,1   ! keypoint számozás bekapcsolás 
/PNUM,line,1 ! line számozás bekapcsolás

! ADATBEVITEL
a=5000 	     ! méret megadás 
h=10000		 ! magassági méret megadás

n1=3	     ! jobbra dőlő blokkok száma
n2=3	     ! balra dőlő blokkok száma

Eacel=200000 ! rugalmassagi modulus
Akm=706.86	 ! keresztmetszet terulete

! PREPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/PREP7	     ! belépés a preprocesszáló részbe

! GEOMETRIA MEGRAJZOLÁSA:
K,1,0,0		 ! bal alsó keypoint megadása
K,2,0,h		 ! bal felső keypoint megadása 
L,1,2		 ! előbbi két pont összekötése egy egyenessel 

! változók kezdeti értékeinek megadása
p1=1		 ! keypoint sorszám
p2=2		 ! keypoint sorszám
x1=0		 ! kezdeti x koordináta

*DO,i,1,n1   ! do ciklus a 3 baloldali (jobbra dőlő) blokk létrehozására 
   p01=p1    ! bal alsó keypointok sorszáma -> 1:p01=1 2:p01=3 3:p01=5
   p02=p2    ! bal felső keypointok sorszáma -> 1:p02=2 2:p02=4 3:p02=6
   p1=p1+2	 ! jobb alsó keypoint sorszám növelése -> 1:p1=3 2:p1=5 3:p1=7
   p2=p2+2	 ! jobb felső keypoint sorszám növelése -> 1:p2=4 2:p2=6 3:p2=8
   x1=x1+a	 ! jobb oldali keypointok x koordinátái -> 1:x1=5000 2:x1=10000 3: x1=15000
   K,p1,x1,0 ! jobb alsó keypointok létrehozása  -> 1:K,3,5000,0 2:K,5,10000,0 3:K,7,15000,0
   K,p2,x1,h ! jobb felső keypointok létrehozása  -> 1:K,4,5000,10000 2:K,6,10000,10000 3:K,8,15000,10000
   L,p01,p1	 ! alső vízszintes vonalak megrajzolása -> 1:L,1,3 2:L,3,5 3:L,5,7
   L,p02,p2	 ! felső vízszintes vonalak megrajzolása -> 1:L,2,4 2:L,4,6 3:L,6,8
   L,p1,p2	 ! jobb oldali függőleges vonalak megrajzolása -> 1:L,3,4 2:L,5,6 3:L,7,8
   L,p01,p2	 ! átlós vonalak megrajzolása -> 1:L,1,4 2:L,3,6 3:L,5,8
*ENDDO       ! do ciklus lezárása

*DO,i,1,n2   ! do ciklus a 3 jobboldali (balra dőlő) blokk létrehozására 
   p01=p1    ! bal alsó keypointok sorszáma -> 1:p01=7 2:p01=9 3:p01=11
   p02=p2    ! bal felső keypointok sorszáma -> 1:p01=8 2:p01=10 3:p01=12
   p1=p1+2	 ! jobb alsó keypoint szorzám növelése -> 1:p1=9 2:p1=11 3:p1=13
   p2=p2+2	 ! jobb felső keypoint szorzám növelése -> 1:p2=10 2:p2=12 3:p2=14
   x1=x1+a	 ! jobb oldali keypointok x koordinátái -> 1:x1=20000 2:x1=25000 3: x1=30000
   K,p1,x1,0 ! jobb alsó keypointok létrehozása -> 1:K,9,20000,0 2:K,11,25000,0 3:K,13,30000,0
   K,p2,x1,h ! jobb felső keypointok létrehozása -> 1:K,10,20000,10000 2:K,12,25000,10000 3:K,14,30000,10000
   L,p01,p1	 ! alső vízszintes vonalak megrajzolása -> 1:L,7,9 2:L,9,11 3:L,11,13
   L,p02,p2	 ! felső vízszintes vonalak megrajzolása -> 1:L,8,10 2:L,10,12 3:L,12,14
   L,p1,p2	 ! jobb oldali függőleges vonalak megrajzolása -> 1:L,9,10 2:L,11,12 3:L,13,14
   L,p02,p1	 ! átlós vonalak megrajzolása -> 1:L,8,9 2:L,10,11 3:L,12,13
*ENDDO       ! do ciklus lezárása

! ANYAGTULAJDONSÁGOK:
MP,ex,1,Eacel			! rugalmassági modulus

! HÁLÓZÁS:
ET,1,link180			! elem típus: link180 (húzott-nyomott rúdelem)
SECTYPE,1,link          ! keresztmetszet típus: link (húzott-nyomott keresztmetszet)
SECDATA,Akm				! keresztmetszet jellemzők (keresztmetszet területe)
LESIZE,all,,,1          ! rúdelem méret megadása (rúd sorszáma:all->összes rúd,méret-,szögméret-,elemek száma vonalanként)
LMESH,all				! összes vonal behálózása link180-as elemekkel

! PEREMFELTÉTELEK:
D,node(0,0,0),all,0             ! 0,0,0 koordinátájú csomópont minden irányú megfogasa
D,node((n1+n2)*a,0,0),uy,0      ! 30000,0,0 koordinátájú csomópont y irányú megfogása
F,node(0,h,0),fx,20000          ! 0,10000,0 koordinátájú csomópontra 20000N x irányú erő megadása
F,node(n1*a,0,0),fy,-20000      ! 15000,0,0 koordinátájú csomópontra -20000N y irányú erő megadása
F,node((n1+1)*a,0,0),fy,-40000  ! 20000,0,0 koordinátájú csomópontra -40000N y irányú erő megadása

ALLSEL                  ! minden kiválasztása
FINISH					! kilépés a preprocessingból

! SOLVING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/SOLU					! belépés a solver-be
SOLVE					! számítás elvégzése
FINISH					! kilépés a solver-ből

! POSTPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
/POST1					! belépés a postprocessor-ba

PLDISP   				! elmozdulás szemléltetése 
PLNSOL,u,sum			! elmozdulásmező abszolútértékének szemléltetése
PLNSOL,u,x				! x irányú elmozdulásmező szemléltetése
PLNSOL,u,y				! y irányú elmozdulásmező szemléltetése

! feszültségek ábrázolása:
ETABLE,Sxxi,ls,1		! szigma x rúdirányú normálfeszültségek a rudak i-edi csomópontjában -> Sxxi
ETABLE,Sxxj,ls,2		! szigma x rúdirányú normáéfeszültségek a rudak j-edi csomópontjában -> Sxxj
PLLS,Sxxi,Sxxj			! szigma x rúdirányú normálfeszültségek ábrázolása
! rúderők ábrázolása:
ETABLE,N,smisc,1		! rúderő az egyes rudakban -> N
PLLS,N,N				! rúderők ábrázolása

!PRRSOL   				! támasztóerők listázása