! VEM alapjai 6.gyak
! Térbeli rácsos tartó - toronydaru
! [N,mm,MPa]

FINISH
/CLEAR

/CWD,'D:\Google_Drive\01_education\05A_VEMA\gyakok21221\gyak6'
*ABBR,START,/input,VEMA_gyak6_static,ans

/VIEW,  1,  0.3    , -0.9    , -0.3 	! nézet beállítás
/ANG,   1,  -130  						! nézet beforgatás
/REPLO  								! újrarajzolás 

! paraméterek:
a=1000	! blokkok szélessége
h=1000	! blokkok magassága
n1=15 	! függőleges rész (törzs) blokkjainak száma
n2=12	! vízszintes tartó (gém/ellengém) helye (hányadik blokknál)
n3=10	! hosszabb vízszintes szakaszon (gémen) a blokkok száma
n4=5	! rövidebb vízszintes szakaszon (ellengémen) a blokkok száma

Eacel=2e5   ! rugalmassagi modulusz
nuacel=0.3  ! Poisson tényező
Akm=10000   ! leresztmetszet területe
Rho=7.8e-9  ! sűrűség

/PNUM,node,1
/PNUM,elem,1

!-------------------------------------------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! PREPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!-------------------------------------------------------------------------------------------------------------------------

/PREP7

! HÁLÓ ELKÉSZÍÍTÉSE
ET,1,180	! végeselem típus link180 - húzott nyomott rúdelem 
SECTYPE,1,link  ! húzott-nyomott keresztmetszet
SECDATA,Akm	    ! keresztmetszet területe 

! csomópont (node) sorszámok 
p1=1
p2=2
p3=3
p4=4

! alsó 4 node megadása
N,p1,-a/2,-a/2
N,p2, a/2,-a/2
N,p3, a/2, a/2
N,p4,-a/2, a/2

! alsó 4 node összekötése végeselemekkel
E,p1,p2
E,p2,p3
E,p3,p4
E,p4,p1

z1=0		! blokkok felső node-jainak z koordinátáinak inicializálása

!!! for ciklus a törzs blokkok megrajzolására!!!!!!!!
*DO,i,1,n1    ! for ciklus i ciklusváltozó megy 1-től n1-ig 
   p01=p1             ! blokkok alsó node-jainak sorszámai
   p02=p2
   p03=p3
   p04=p4
   p1=p01+4           ! blokkok felső node-jainak sorszámai
   p2=p02+4
   p3=p03+4
   p4=p04+4
   z1=z1+h		      ! blokkok felső node-jainak z koordinátái 
   N,p1,-a/2,-a/2,z1  ! blokkok felső node-jainak megadása
   N,p2, a/2,-a/2,z1
   N,p3, a/2, a/2,z1
   N,p4,-a/2, a/2,z1 
   E,p01,p1           ! függőleges végeselemek berajzolása
   E,p02,p2
   E,p03,p3
   E,p04,p4
   E,p01,p2           ! átlós végeselemek berajzolása 
   E,p02,p3
   E,p03,p4
   E,p04,p1 
   E,p1,p2            ! fenti vízszintes végeselemek berajzolása
   E,p2,p3
   E,p3,p4
   E,p4,p1
   *IF,i,eq,n2,then   ! ha i=n2 akkor tárolja el az aktuális blokk alsó node-jainak sorszámait
      p11=p01
      p12=p02
      p13=p03
      p14=p04
      z2=z1-h 	      ! az aktuális blokk aljának magassági koordinátája
   *ENDIF
*ENDDO

!! törzscsúcs megrajzolása !!!!!!!!!!!!!!!!!!!!!
pt0=p4+1		! legfelső node sorszáma 
N,pt0,0,0,z1+h	! legfelső node létrehozása 
E,p1,pt0        ! legfelső node összekötése az alatta lévő blokk 4 node-jával
E,p2,pt0
E,p3,pt0
E,p4,pt0

!! új változók inicializálása a gém sorszámozáshoz
p31=pt0+1
p32=pt0+2
p33=pt0+3

!! gém csonkrészének megrajzolása: 
x0=a/2+a
N,p31,x0,-a/2,z2
N,p32,x0, a/2,z2
N,p33,x0, 0  ,z2+h
E,p12,p31
E,p13,p32
E,p12,p32
E,p31,p32
E,p32,p33
E,p33,p31
E,p12,p33
E,p13,p33

!!! for ciklus a gém megrajzolására!!!!!!
*DO,i,1,n3
   P21=P31				! baloldali node-ok sorszámai
   P22=P32
   P23=P33
   p31=p21+3            ! jobboldali node-ok sorszámai
   p32=p22+3
   p33=p23+3
   x0=x0+a              ! blokkok jobboldali node-jainak x koordinátája 
   N,p31,x0,-a/2,z2     ! blokkok jobboldali node-jainak megadása
   N,p32,x0, a/2,z2
   N,p33,x0, 0  ,z2+h
   E,p21,p31            ! vízszintes elemek megrajzolása
   E,p22,p32
   E,p23,p33
   E,p21,p32            ! átlós elemek megrajzolása
   E,p22,p33
   E,p23,p31
   E,p31,p32            ! függőleges síkban lévő elemek megrajzolása 
   E,p32,p33
   E,p33,p31
*ENDDO

pr0=p33 	! utolsó felső node a gémen, ahová majd a tartókötél kapcsolódik

! terhelés node-jai:
pterh1=p31
pterh2=p32

!! változók inicializálása az ellengém sorszámozáshoz
p31=pr0+1
p32=pr0+2
p33=pr0+3

! ellengém csonkrészének megrajzolása: 
x0=-a/2-a
N,p31,x0,-a/2,z2
N,p32,x0, a/2,z2
N,p33,x0, 0  ,z2+h
E,p11,p31
E,p14,p32
E,p11,p32
E,p31,p32
E,p32,p33
E,p33,p31
E,p11,p33
E,p14,p33

!!! for ciklus az ellengém megrajzolására!!!!!!
*DO,i,1,n4
   P21=P31				! jobboldali node-ok sorszámai
   P22=P32
   P23=P33
   p31=p21+3            ! baloldali node-ok sorszámai
   p32=p22+3
   p33=p23+3
   x0=x0-a              ! blokkok baloldali node-jainak x koordinátája 
   N,p31,x0,-a/2,z2     ! blokkok baloldali node-jainak megadása
   N,p32,x0, a/2,z2
   N,p33,x0, 0  ,z2+h
   E,p21,p31            ! vízszintes elemek megrajzolása
   E,p22,p32
   E,p23,p33
   E,p21,p32            ! átlós elemek megrajzolása
   E,p22,p33
   E,p23,p31
   E,p31,p32            ! függőleges síkban lévő elemek megrajzolása
   E,p32,p33
   E,p33,p31
*ENDDO

pl0=p33		! utolsó felső node az ellengémen, ahová majd a tartókötél kapcsolódik

! ellensúly node-jai:
pellens1=p31 
pellens2=p32 
pellens3=p31-3
pellens4=p32-3

!! két felső tartókötél megrajzolása
E,pt0,pr0
E,pt0,pl0

! ANYAGJELLEMZŐK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

MP,ex,1,Eacel		!rugmodulusz megadás
MP,prxy,1,nuacel    !Poisson tényező megadás
MP,dens,1,Rho	    !sűrűség t/mm3

! PEREMFELTÉTELEK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! megfogások megadása (csuklók)
D,1,all,0
D,2,all,0
D,3,all,0
D,4,all,0

!D,1,ux,0,,,,uy,uz 
!D,2,ux,0,,,,uy,uz 
!D,3,ux,0,,,,uy,uz 
!D,4,ux,0,,,,uy,uz 

! terhelések megadása
ACEL,0,0,10000		  ! gravitációs gyorsulás mm/s2

! teher és ellensúly megadása

! egyik lehetőség: koncentrált erőkkel
!F,pterh1,fz,-10000
!F,pterh2,fz,-10000
!F,pellens1,fz,-10000
!F,pellens2,fz,-10000
!F,pellens3,fz,-10000
!F,pellens4,fz,-10000

! VAGY

! másik lehetőség: erők helyett tömegpontok elhelyezése
ET,2,mass21     ! végeselem típus: mass21 - tömeg elem 
KEYOPT,2,1,0	! real constants megadása tömeg és tehetetlenségi nyomaték jellemzőkkel
KEYOPT,2,3,2 	! 3-D tömeg tehetetlenségi nyomaték nélkül
R,2,1           ! tömeg [t]
TYPE,2          ! 2. elem kiválasztása
REAL,2          ! 2. real constant kiválasztása
E,pterh1        ! tömegpont elhelyezése
E,pterh2        ! tömegpont elhelyezése
E,pellens1      ! tömegpont elhelyezése
E,pellens2      ! tömegpont elhelyezése
E,pellens3      ! tömegpont elhelyezése
E,pellens4      ! tömegpont elhelyezése

ALLSEL          ! minden kiválasztása
FINISH          ! kilépés a preprocessorból

!-------------------------------------------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! SOLVING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!-------------------------------------------------------------------------------------------------------------------------

/SOLU					! belépés a solver-be
SOLVE					! számítás elvégzése
FINISH					! kilépés a solver-ből

!-------------------------------------------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! POSTPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!-------------------------------------------------------------------------------------------------------------------------

/POST1                  ! belépés a postprocessorba

ESEL,s,type,,1          !1-es típusú elemek (link elemek) kiválasztása

PLNSOL,u,sum			! elmozdulásmező abszolútértékének szemléltetése
PLNSOL,u,x				! x irányú elmozdulásmező szemléltetése
PLNSOL,u,y				! y irányú elmozdulásmező szemléltetése

! elem-táblázat létrehozása
ETABLE,Sxxi,ls,1		! szigma x rúdirányú normálfeszültségek a rudak i-edi csomópontjában -> Sxxi
ETABLE,Sxxj,ls,2		! szigma x rúdirányú normáéfeszültségek a rudak j-edi csomópontjában -> Sxxj
ETABLE,N,smisc,1		! rúderő az egyes rudakban -> N

PLETAB,N 	     	! rúderők ábrázolása
!PLLS,Sxxi,Sxxj			! szigma x rúdirányú normálfeszültségek ábrázolása
!PLLS,N,N				! rúderők ábrázolása

PRRSOL					! támasztóerők listázása
PRNSOL,u,comp		    ! node-ok elmozdulás eredmények lekérése
PRESOL,s,prin		    ! feszültség eredmények kilistázása 

ALLSEL                  ! minden kiválasztása
CDWRITE,all,static2workbench,cdb ! exportálás