! VEM alapjai 10. gyak
! Rudakkal merevített szendvics szerkezet
! [mm,N,MPa]

FINISH     ! kilépés minden folyamatból
/CLEAR     ! memória törlése

! munkakönyvtár definiálása, indító gomb létrehozása
/CWD,'D:\Google_Drive\01_education\05A_VEMA\gyakok21221\gyak8'
*ABBR,START,/input,VEMA_gyak8,ans

/VIEW,  1,  0.7    , -0.6    ,  0.5
/ANG,   1,  -60  
/REPLO  								! újrarajzolás 

! VÁLTOZÓK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

na=10      ! elemszám x irányban a lemezen
nb=20      ! elemszám y irányban a lemezen

es=10      ! elem méret a lemezen
h=10       ! két lemez távolsága egymástól
v=1        ! lemez vastagsága

!--------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! I PREPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--------------------------------------------------------------------------------------

/PREP7        	  ! belépés a preprocessorba

a=es*na           ! lemez egyik hosszmérete
b=es*nb           ! lemez másik hosszmérete
BLC4,0,0,a,b,h    ! téglatest rajzolás

! ANYAGJELLEMZŐK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
MP,ex,1,2e5       ! rugalmassági modulus megadása
MP,nuxy,1,0.3     ! Poisson tényező megadása

! VÉGESELEMEK DEFINIÁLÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ET,1,shell181  	  ! 1. elem: beam elem (188: 2 node-os, 189: 3 node-os)
SECTYPE,1,shell   ! 1. section típus: shell
SECDATA,v         ! vastagság megadása

ET,2,link180      ! 2. elem: húzott-nyomott rúdelem
SECTYPE,2,link    ! 2. section: link (húzott-nyomott keresztmetszet)
SECDATA,100       ! KM területe

! LEMEZEK BEHÁLÓZÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
TYPE,1            ! 1. elem kiválasztása
SECNUM,1          ! 1. section kiválasztása
ESIZE,es          ! elemméret megadása
MSHAPE,0          ! végeselem alakja (0: négyszög, 1: háromaszög)
mshkey,1          ! 1:mapped 0:free struktúrált háló létrehozás
ASEL,s,loc,z,0    ! alsó felület kijelölése
ASEL,a,loc,z,h    ! felső felület kijelölése
AMESH,all         ! összes felület behálózása

! MEREVÍTŐ RUDAK ELHELYEZÉSE !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
TYPE,2            ! 2. elem kiválasztása
SECNUM,2          ! 2. section kiválasztása

*DO,i,0,na-1
   *DO,j,0,nb-1
      NSEL,s,loc,x,i*es
      NSEL,r,loc,y,j*es
      NSEL,r,loc,z,0
      *GET,n1,node,0,num,min    !csp sorszám lekérdezés az n1 változóba
      NSEL,s,loc,x,i*es
      NSEL,r,loc,y,j*es
      NSEL,r,loc,z,h
      *GET,n2,node,0,num,min    !csp sorszám lekérdezés az n2 változóba
      E,n1,n2
   *ENDDO
*ENDDO

*DO,i,0,na-1
   *DO,j,0,nb-1
      NSEL,s,loc,x,i*es
      NSEL,r,loc,y,j*es
      NSEL,r,loc,z,0
      *GET,n1,node,0,num,min     !csp sorszám lekérdezés az n1 változóba
      NSEL,s,loc,x,(i+1)*es
      NSEL,r,loc,y,j*es
      NSEL,r,loc,z,h
      *GET,n2,node,0,num,min     !csp sorszám lekérdezés az n2 változóba
      E,n1,n2
   *ENDDO
*ENDDO

*DO,i,0,na-1
   *DO,j,0,nb-1
      NSEL,s,loc,x,i*es
      NSEL,r,loc,y,j*es
      NSEL,r,loc,z,0
      *GET,n1,node,0,num,min     !csp sorszám lekérdezés az n1 változóba
      NSEL,s,loc,x,i*es
      NSEL,r,loc,y,(j+1)*es
      NSEL,r,loc,z,h
      *GET,n2,node,0,num,min     !csp sorszám lekérdezés az n2 változóba
      E,n1,n2
   *ENDDO
*ENDDO

! PEREMFELTÉTELEK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

! fix megfogások megadása körben a z=0 felületen
NSEL,s,loc,x,0
NSEL,a,loc,x,na*es
NSEL,a,loc,y,0
NSEL,a,loc,y,nb*es
NSEL,r,loc,z,0

D,all,all,0

! terhelés megadása az ellenkező felület közepén lévő csp-okra
NSEL,s,loc,x,na*es/4,na*es*3/4
NSEL,r,loc,y,nb*es/4,nb*es*3/4
NSEL,r,loc,z,h
F,all,fz,-1

ALLSEL          ! minden kijelölése
FINISH          ! kilépés a preprocessorból

!--------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! II SOLVING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--------------------------------------------------------------------------------------

/SOLU           ! belépés a solverbe
SOLVE           ! számítás elvégzése
FINISH          ! kilépés a solverből

!--------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! III POSTPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!--------------------------------------------------------------------------------------

/POST1          ! belépés a postprocessorba
PLNSOL,u,sum    ! elmozdulásmező ábrázolása
PLNSOL,s,eqv    ! redukált feszültségmező ábrázolása

ESEL,s,type,,2  ! 2-es elemtípus kiválasztása        

ETABLE,rudero,smisc,1  ! rúderő ábrázolása
PLETAB,rudero,noav