! Végeslemes modellezés gyakorlat
! rugalmas féltér
! [N,mm,MPa]

FINISH     ! kilépés minden folyamatból
/CLEAR     ! memória törlése

! munkakönyvtár beállítása:
/CWD, 'D:\Google_Drive\01_education\07_VEA\APDL_20211\rugalmas_felter'
! indítógomb létrehozása:
*ABBR,START,/input,rugalmas_felter,ans

! VÁLTOZÓK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
Rhs=10000			! rugalmas féltér sugara
rcyl=25				! merev henger sugara
depth=0.01			! benyomás mélysége
rmax=30				! kontakt tartomány sugara
ces=0.1				! kontakt tartomány elemmérete mm-ben
Ren=10				! féltér tartomány elemmérete kerületi elemszámban
lay=5				! kontankt tartomány rétegeinek száma
E=2e5				! rugalmassági modulusz
nu=0.3				! Poisson tényező

!-------------------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! PREPROCESING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!-------------------------------------------------------------------------------------------------

/PREP7				! belépés a preprocessorba

! GEOMETRIA MEGRAJZOLÁSA, ELŐKÉSZÍTÉSE HÁLÓZÁSHOZ !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
CYL4,0,0,Rhs,0,Rhs,-90	! negyedkör megrajzolása (középpont, kezdő sugár, szög, vég sugár, szög)
K,10,0,-ces*lay			! 10-es pont elhelyezése (0,-2)mm-re
K,11,rmax,-ces*lay		! 11-es pont elhelyezése (30,-2)mm-re
K,12,rmax,0			    ! 12-es pont elhelyezése (30,0)mm-re
LSEL,none				! összes vonal inaktiválása
L,10,11					! vonal 10-es és 11-es pontok közé
L,11,12					! vonal 11-es és 12-es pontok közé
ASBL,all,all			! összes felületből az összes aktív vonal kivonása ->felület elvágása

ASEL,s,loc,x,0,rmax		! 0 és 30 mm közti felületek kijelölése
CM,contarea,area		! kijelölt felület elnevezése contarea-nak

ASEL,inve				! kijelölés megfordítása
CM,halfspace,area		! kijelölt felület elnevezése halfspace-nek

ALLSEL					! minden kijelölése

! ANYAGTULAJDONSÁGOK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
MP,ex,1,E				! rugalmassági modolusz megadása
MP,nuxy,1,nu			! Poisson tényező megadása

! HÁLÓZÁS !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ET,1,183     			! 2D elemtípus megadása(182: lineáris, 183: másodfokú)
KEYOPT,1,3,1			! 2D feladat típusa (1:FSZ, 2:SA, 3:ÁSF)

MSHAPE,0,2d				! elem alakja (0:négszög, 1:háromszög)
MSHKEY,0				! hálózási technika (0: struktúrált, 1:szabad)
DESIZE,1,1,9999,,,ces,ces ! elemméret megadása
AMESH,contarea			! contarea tartomány behálózása

MSHAPE,1,2d				! elem alakja (0:négszög, 1:háromszög)
MSHKEY,0				! hálózási technika (0: struktúrált, 1:szabad)
oes=Rhs*3.1415/2/Ren    ! elemméret: (R*PI)/2/Ren
DESIZE,1,1,9999,,,ces,oes,0.2 !elemméret megadása
AMESH,halfspace			! halfspace tartomány behálózása

ALLSEL				! minden kijelölése

! PEREMFELTÉTELEK MEGADÁSA !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
CSYS,1					! áttérés henger koordináta rendszerre
NSEL,s,loc,x,Rhs		! origótól Rhs távolságra lévő csomópontok kijelölése
D,all,ux,0				! sugárirányú elmozdulás 0
D,all,uy,0				! érintő irányú elmozdulás 0
CSYS,0					! visszatérés derékszögű koordinátarendszerbe
NSEL,s,loc,y,0			! y=0-nál lévő csomópontok kijelölése
NSEL,r,loc,x,0,rcyl		! a fenti kijelölésből x=(0,rcyl) közti pontok kijelölése
D,all,uy,-depth			! -depth mértékű eltolása a kijelölt pontoknak

ALLSEL					! minden kijelölése
FINISH					! kilépés a preprocessorból

!-------------------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! SOLVING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!-------------------------------------------------------------------------------------------------

/SOLU              		! belépés a solverbe (megoldóba)
SOLVE                	! számítás elvégzése
FINISH               	! kilépés a solverből

!-------------------------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! POSTPROCESSING !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!-------------------------------------------------------------------------------------------------

/POST1               	! belépés a postprocessorba (kiértékelőbe)

PLNSOL,u,y      		! elmozdulásmező szemléltetése
plnsol,s,y              ! szigma_y feszültségeloszlás szemléltetése

! Függvényábrázolások:
PATH,cont,2,3,1000		! nyomvonal definiálása (név,definiáló pontok száma, változók száma, pontok közti felosztás)
PPATH,1,,0,0			! nyomvonal kezdőpontja
PPATH,2,,rcyl,0			! nyomvonal végpontja
PDEF,cpfem,s,y			! 5.ábrázolandó változó: kontakt nyomás(=szigma y) végeselemből
PDEF,cpan,s,y	        ! 6.ábrázolandó változó: kontakt nyomás analitikusan (felül lesz írva)
PDEF,cpdif,s,y	     	! 7.ábrázolandó változó: eltérés a két nyomás között
PCALC,add,cpfem,cpfem,,-1	! cpfem szorzása -1-gyel (nyomás szigma_y -1-szerese)

PAGET,cpmat,table		! nyomvonalinformációk cpmat nevű mátrixba rendezése

*GET,row,parm,cpmat,dim,1	! cpmat mátrix sorainak száma
*GET,col,parm,cpmat,dim,2	! cpmat mátrix oszlopainak száma

p0=(E*depth)/(3.1415*(1-nu*nu)*rcyl)	! analitikus p0 kiszámítása

*DO,i,1,row
	cpmat(i,6)=(p0/sqrt(1-(cpmat(i,1)*cpmat(i,1)/(rcyl*rcyl))))			! cpmat 6.oszlopa
	cpmat(i,7)=ABS(cpmat(i,5)-cpmat(i,6))								! cpmat 7.oszlopa
*ENDDO

PAPUT,cpmat,table		! frissített cpmat lekérése	

/YRANGE,0,200			! y tengely határai
PLPATH,cpan,cpfem		! analitikus és femes függvények ábrázolása
*ASK,next,OK,0          ! felugró ablak a következő ábrához
/YRANGE,0,20    		! y tengely határai
PLPATH,cpdif            ! eltérés ábrázolása

*GET,nn,node,0,count	! csomópontszám lekérése